AutoHotkeyで英語キーボードの日本語変換キーをalt短押しカスタマイズ

altキー短押しで以下の動作をします

左alt: IMEオンの場合、「IME OFF」仮想キーにリマップ

右alt: IMEオフの場合、「IME ON」仮想キーにリマップ

あとは、IMEの設定でいい感じに（後述）

詳しくは以下の記事を参照:

動機

時々altキーが押しっぱなし状態になってしまい解除できなくなる現象

AutoHotkey のスクリプト

code:ahk

; LICENSE: MIT

; Author: Takayuki Shimizukawa 2026

IME_GET(WinTitle := "A") {

; アクティブウィンドウのハンドルを取得。ハンドルはWindows内部でウィンドウを一意に識別する整数値

hwnd := WinExist(WinTitle)

; Win32 API ImmGetDefaultIMEWnd を呼び出し、そのウィンドウに対応するIME管理ウィンドウのハンドルを取得。

; IMEはウィンドウごとに隠しウィンドウを持っていて、状態や設定が管理されている。

DefaultIMEWnd := DllCall("imm32\ImmGetDefaultIMEWnd", "Ptr", hwnd, "Ptr")

; SendMessage でIME管理ウィンドウにメッセージを送って状態を取得。

; | 引数 | 値 | 意味

; | ---- | ------------- | ---------------------------- |

; | 第1引数 | DefaultIMEWnd | 送信先（IME管理ウィンドウ）

; | 第2引数 | 0x0283 | WM_IME_CONTROL（IME制御メッセージ）

; | 第3引数 | 0x005 | IMC_GETOPENSTATUS（オープン状態を取得）

; | 第4引数 | 0 | 未使用（0固定）

return DllCall("SendMessage", "Ptr", DefaultIMEWnd, "UInt", 0x0283, "Int", 0x005, "Int", 0, "Int")

}

; 未定義のダミーキー（vk07）を送信し、「Alt単体の空打ち」でWindowsのメニューバーが開いてしまう挙動を抑制

~*LAlt::Send("{Blind}{vk07}")

~*RAlt::Send("{Blind}{vk07}")

LAlt Up:: {

; 既にIMEオフなら何もしない、オンのときだけオフにする

if (IME_GET() != 0)

Send("{vk1A}") ; VK_IME_OFF

;Send("{vk1D}") ; VK_NONCONVERT 無変換 を経由したい場合

}

RAlt Up:: {

; 既にIMEオンなら何もしない、オフのときだけオンにする

if (IME_GET() == 0)

Send("{vk16}") ; VK_IME_ON

; Send("{vk1C}") ; VK_CONVERT 変換 を経由したい場合

}

; Virtual-Key コード (Winuser.h) - Win32 apps | Microsoft Learn

変換 / 無変換 を経由したい場合、とは

これによって、このスクリプト単体では「英語キーボードでも「変換」「無変換キー」を押したい」を実現

これらの動作はキーカスタマイズで変更できます。

code:keymap.txt

Composition OFF IMEOff ; 元は CancelAndIMEOff

Conversion OFF IMEOff ; 元は CancelAndIMEOff

Precomposition OFF IMEOff ; 元は CancelAndIMEOff

これでATOKで「確定+IMEを無効化」が出来ました！

code:mozkey-ime-keymap.txt

Composition OFF Commit|IMEOff

Conversion OFF Commit|IMEOff

文字入力中のIME OFF では入力文字が未確定のまま残ってしまいます。

そこで、AutoHotkeyのマッピングを「変換」「無変換」に向けたところ、期待する動作になりました。

o 「無変換」で変換中と、入力中文字列を確定してIME Off

o 「変換」でIME On

文字入力中のIME OFF では入力文字が未確定のまま残ってしまいます。

そこで、AutoHotkeyのマッピングを「変換」「無変換」に向けたところ、部分的に、期待する動作になりました。

o 「無変換」で変換中文字列を確定してIME Off

x 「無変換」で入力中文字列は確定もキャンセルもせず残ったまま IME Off

o 「変換」でIME On

割り当てカスタマイズしてもだめだった

https://scrapbox.io/files/6a32ab0b2ba3627f4ebcd311.png

2026/6/20 時点

今のところ、MS Copilot Keybaord, Google IME, Mozkey は合格。