husk から Redshift で USD Stage のレンダリング
exports stage (LOPs Network)
husk 側からフレーム, 解像度, 出力先等色々指定できるので, それ以外を rendersettings として Stage に保存しておく
husk parameters
Windows
code:config.ini
HOUDINI_REDSHIFT_VERSION=20.5.278
code:render_shot01.bat
@echo off
rem Read ./config.ini
for /f "tokens=1,2 delims==" %%a in (config.ini) do (
if %%a==HOUDINI_REDSHIFT_VERSION set HOUDINI_VERSION=%%b
)
rem Redshift: for Houdini
set "REDSHIFT_COREDATAPATH=%PROGRAMDATA%/redshift"
set "HOUDINI_PATH=%REDSHIFT_COREDATAPATH%/Plugins/Houdini/%HOUDINI_VERSION%;%HOUDINI_PATH%"
set "PATH=%REDSHIFT_COREDATAPATH%/bin;%PATH%"
rem Redshift: for Solaris
set "PXR_PLUGINPATH_NAME=%REDSHIFT_COREDATAPATH%/Plugins/Solaris/%HOUDINI_VERSION%;%PXR_PLUGINPATH_NAME%"
rem Redshift: for H20~ OCIO Warning
set "OCIO=%REDSHIFT_COREDATAPATH%/Data/OCIO/config.ocio"
rem Update $PATH
set "HOUDINI_PATH=%HOUDINI_PATH%;&"
set "PATH=%PROGRAMFILES%/Side Effects Software/Houdini %HOUDINI_VERSION%/bin;%PATH%"
rem run husk
husk.exe ^
--usd-input "houdini-projects/geo/redshift.preview.usda" ^
--output "render/redshift_preview_shot01.$F6.exr" ^
--purpose "geometry,render" ^
--frame 1 ^
--frame-count 100 ^
--frame-inc 1 ^
--renderer Redshift ^
--threads -1
Linux