precision mediump float;
uniform float time;
uniform vec2 resolution;
const float PI=acos(-1.0);
vec2 rot(vec2 p,float a){return vec2(p.x*cos(a)-p.y*sin(a),p.x*sin(a)+p.y*cos(a));}

//-----

vec3 circle(vec2 p,float r){
    // 瑠璃色
    vec3 ruriiro=vec3(42.,92.,170.)/255.;
    vec3 white=vec3(1.);

    if(length(p)>6./6.*r) return white;
    if(length(p)>5./6.*r) return ruriiro;
    if(length(p)>4./6.*r) return white;
    if(length(p)>3./6.*r) return ruriiro;
    if(length(p)>2./6.*r) return white;
    if(length(p)>1./6.*r) return ruriiro;
    
    return white;
}

vec3 seigaiha(vec2 p,float r){
    // 青海波
    vec2 q=p;
    float f=floor(p.x);
    q=fract(q);
    float dif=step(1.,mod(f,2.))*r;
    q.x-=dif;
    
    if(length(q+vec2(.0,r/2.))<r) return circle(q+vec2(.0,r/2.),r);
    if(length(q+vec2(-r,.0))<r) return circle(q+vec2(-r,.0),r);
    if(length(q+vec2(r,.0))<r) return circle(q+vec2(r,.0),r);
    if(length(q+vec2(.0,-r/2.))<r) return circle(q+vec2(.0,-r/2.),r);
    return vec3(1.);
}

//-----

float rect(vec2 p, float x1, float y1, float x2, float y2) {
	float d = .00001; // 線のエッジ
	return (
		smoothstep(x1, x1 + d, p.x) * smoothstep(x2, x2 - d, p.x) * 
		smoothstep(y1, y1 + d, p.y) * smoothstep(y2, y2 - d, p.y)
	);
}

vec3 sayaUnit(vec2 p,vec2 rev){
    // 紺
    vec3 kon=vec3(.0,26.,67.)/255.;
    // 瑠璃紺
    vec3 rurikon=vec3(34.,75.,144.)/255.;
    
    // note
    // p : 0.0-1.0
    // rev : border
    vec2 q=p;
    q.x=step(.5,rev.x)*q.x+step(rev.x,.5)*(1.-q.x);
    q.y=step(.5,rev.y)*q.y+step(rev.y,.5)*(1.-q.y);

    float pat = .0;
    float block = 1./5.;
    float u=.5*block;
    
    pat=clamp(
        rect(q,.0,.0,u,9.*u)
        +rect(q,u,7.*u,7.*u,9.*u)
        +rect(q,3.*u,5.*u,5.*u,7.*u)
        ,.0,1.);
    q=1.-q;
    pat=clamp(pat+
        rect(q,.0,.0,u,9.*u)
        +rect(q,u,7.*u,7.*u,9.*u)
        +rect(q,3.*u,5.*u,5.*u,7.*u)
        ,.0,1.);
    return kon*pat+rurikon*step(pat,.1);
}

vec3 sayagata(vec2 p,float m){
    // 紗綾形
    vec2 q=p*m;
    vec2 ind=floor(p*m);
    q=fract(q);
    vec2 rev=step(.0,(mod(ind,2.)-1.));
    vec3 col=sayaUnit(q,rev);
    return col;
}

//-----

void main(void)
{
    vec3 col = vec3(.0);

    //-----
    
    vec2 p = (gl_FragCoord.xy*2.0-resolution.xy)/resolution.y;
    p*=5.;
    vec3 colSeigaiha=vec3(0.);
    
    float r=1.;
    colSeigaiha=seigaiha(p,r);
    
    //-----
    
    p = (gl_FragCoord.xy*2.0-resolution)/min(resolution.x,resolution.y);
    vec3 colSayagata = vec3(.0);
    vec2 q=p;
    
    q*=vec2(.75,1.75);
    q=rot(q,PI/4.+.00001);
    colSayagata=sayagata(q, 3.);
    
    //-----
    
    float t = mod(time, 4.0);
    col = step(t, 2.0) * colSeigaiha + step(2.0, t) * colSayagata;
    
	gl_FragColor = vec4(col, 1.);
}