ImageJで FRET.CFPのRatio画像を作る

code: IMD_ImageJ.ijm

// ====================================================================================

// Create intensity modulated display (IMD) images for representing FRET/CFP ratio images. Made by Yohei Kondo

// ====================================================================================

// Before starting this macro, please subtract background values from CFP and FRET images.

// In addition, please make "divide" images by "image calculater>Divide (32 bit float)"

// This macro requires donor images (e.g., CFP) and divide images.

Dialog.create("IMD parameters");

Dialog.addNumber("Ratio Max", 2.0); // Max ratio value

Dialog.addNumber("Ratio Min", 1.0); // Min ratio value

Dialog.addNumber("Donor Max", 100); // Representative donor intensity

Dialog.addNumber("Donor Min", 0); // Representative donor background intensity

Dialog.addString("Ratio stack name", "Ratio.tif"); // The name of Divide images

Dialog.addString("Donor stack name", "BG-CFP.tif"); // The name of donor images

Dialog.show();

rmax = Dialog.getNumber();

rmin = Dialog.getNumber();

dmax = Dialog.getNumber();

dmin = Dialog.getNumber();

rname = Dialog.getString();

dname = Dialog.getString();

rrange = rmax - rmin

drange = dmax - dmin

run("Conversions...", " ");

selectWindow(dname);

run("Duplicate...", "duplicate");

rename("mask");

run("32-bit");

run("Subtract...", "value=&dmin stack");

run("Divide...", "value=&drange stack");

run("Min...", "value=0 stack");

run("Max...", "value=1 stack");

selectWindow(rname);

run("Duplicate...", "duplicate");

rename("tempratio");

run("32-bit");

changeValues(NaN, NaN, 0);

run("Subtract...", "value=&rmin stack");

run("Divide...", "value=&rrange stack");

run("Min...", "value=0 stack");

run("Max...", "value=1 stack");

run("Multiply...", "value=255 stack");

run("8-bit");

//run("Enhance Contrast", "saturated=0.35");

//run("Duplicate...", "duplicate");

//selectWindow("tempratio");

run("physics");

run("RGB Color");

run("RGB Stack");

run("Split Channels");

selectWindow("C1-tempratio");

run("32-bit");

selectWindow("C2-tempratio");

run("32-bit");

selectWindow("C3-tempratio");

run("32-bit");

imageCalculator("Multiply stack", "C1-tempratio", "mask");

selectWindow("C1-tempratio");

rename("red");

run("8-bit");

imageCalculator("Multiply stack", "C2-tempratio", "mask");

selectWindow("C2-tempratio");

rename("green");

run("8-bit");

imageCalculator("Multiply stack", "C3-tempratio", "mask");

selectWindow("C3-tempratio");

rename("blue");

run("8-bit");

//run("Merge Channels...", "c1=red c2=green c3=blue keep");

run("Merge Channels...", "c1=red c2=green c3=blue");

run("Conversions...", "scale");

Fiji/ImageJのインストール

1. Fiji/ImageJをダウンロードする。ZipをunzipしたらFiji.appというフォルダができる。その中に、ImageJ-win64.exeという実行ファイルがあるので、それをダブルクリック（Windowsの場合）でImageJが立ち上がる。

2. 添付のIMD_ImageJ.ijmをImageJのフォルダの下にあるPluginsのフォルダに入れてImageJを立ち上げると、Pluginsのタブを押し、下の方に IMD_ImageJというマクロのショートカットができる。

Ratio画像の前の下準備

1. FRET画像、CFP画像からBackgroundを引く。ImageJならBackground Subtraction (Rolling ball法)で大き目のサイズで引くか、背景の大体の値（一定値）をProcess > Math > Subtract で引けばOK。後者の方がartifactは出にくいが、前者の方が培地からの自家蛍光（画面の真ん中が高く、端に近づくについれて蛍光輝度が下がるもの）などが除去しやすい。

2. 1の画像をそれぞれBG-FRET.tifとBG-CFP.tifと名付ける（Images > Rename）

3. 単純な割り算画像を作る。Process > Image Calculator で Image1にBG-FRET.tif、Image2にBG-CFP、OperationはDivide、Create new windowと32-bit (float) resultをチェック。

4. 出来た画像を、Ratio.tifと名付ける（Images > Rename）

IMD_ImageJの実行

1. IMD_ImageJ.ijmを実行。Plugins > Macro (一番上にある）> Run （ちなみにEditで編集できる）

2. パラメーターを入れていく

1. Ratio Max: Ratioの最大の値（今回は2.7にした。画像を見ながら微調整する）

2. Ratio Min: Ratioの最小の値（今回は1.6にした。微調整する）

3. Donor Max: Donor (= BG-CFP画像）の中で注目したい細胞の平均的な蛍光輝度の値を入れる。

4. Donor Min: Backgroundが引かれているなら、0でＯＫ

5. Ratio stack name: Ratio.tif (下準備でImage Calculatorで作ったDivide画像の名前）

6. Donor stack name: BG-CFP.tif (下準備で作ったbackground値を引いたCFP画像）

3. あとはOKでできる。

4. Ratio Max, Min, Donor Maxの値を変えて見やすい画像に微調整する。

あまり青すぎたり赤すぎたりするとRatioが飽和しているので変化が見えない。理想は、刺激前とかコントロールは緑っぽい感じになるようにMax, Minの値を調整し、刺激後などで赤くなったり青くなったりするという画像。